Merge pull request #29 from paulo-raca/buzzer-sample

Added example to use buzzer (tone/noTone) for MIDI playback

Author: facchinm

examples/MIDIUSB_buzzer/MIDIUSB_buzzer.ino

@@ -0,0 +1,99 @@
+/*
+ * MIDIUSB_buzzer.ino
+ *
+ * Author: Paulo Costa
+ */ 
+
+#include <MIDIUSB.h>
+#include "pitchToFrequency.h"
+
+#define BUZZ_PIN 9
+
+const char* pitch_name(byte pitch) {
+  static const char* names[] = {"C", "C#", "D", "D#", "E", "F", "F#", "G", "G#", "A", "A#", "B"};
+  return names[pitch % 12];
+}
+
+int pitch_octave(byte pitch) {
+  return (pitch / 12) - 1;
+}
+
+void noteOn(byte channel, byte pitch, byte velocity) {
+  tone(BUZZ_PIN, pitchFrequency[pitch]);
+
+  Serial.print("Note On: ");
+  Serial.print(pitch_name(pitch));
+  Serial.print(pitch_octave(pitch));
+  Serial.print(", channel=");
+  Serial.print(channel);
+  Serial.print(", velocity=");
+  Serial.println(velocity);
+}
+
+void noteOff(byte channel, byte pitch, byte velocity) {
+  noTone(BUZZ_PIN);
+
+  Serial.print("Note Off: ");
+  Serial.print(pitch_name(pitch));
+  Serial.print(pitch_octave(pitch));
+  Serial.print(", channel=");
+  Serial.print(channel);
+  Serial.print(", velocity=");
+  Serial.println(velocity);
+}
+
+void controlChange(byte channel, byte control, byte value) {
+  Serial.print("Control change: control=");
+  Serial.print(control);
+  Serial.print(", value=");
+  Serial.print(value);
+  Serial.print(", channel=");
+  Serial.println(channel);
+}
+
+void setup() {
+  Serial.begin(115200);
+}
+
+void loop() {
+  midiEventPacket_t rx = MidiUSB.read();
+  switch (rx.header) {
+    case 0:
+      break; //No pending events
+      
+    case 0x9:
+      noteOn(
+        rx.byte1 & 0xF,  //channel
+        rx.byte2,        //pitch
+        rx.byte3         //velocity
+      );
+      break;
+      
+    case 0x8:
+      noteOff(
+        rx.byte1 & 0xF,  //channel
+        rx.byte2,        //pitch
+        rx.byte3         //velocity
+      );
+      break;
+      
+    case 0xB:
+      controlChange(
+        rx.byte1 & 0xF,  //channel
+        rx.byte2,        //control
+        rx.byte3         //value
+      );
+      break;
+      
+    default:
+      Serial.print("Unhandled MIDI message: ");
+      Serial.print(rx.header, HEX);
+      Serial.print("-");
+      Serial.print(rx.byte1, HEX);
+      Serial.print("-");
+      Serial.print(rx.byte2, HEX);
+      Serial.print("-");
+      Serial.println(rx.byte3, HEX);
+  }
+}
+

src/pitchToFrequency.h

@@ -0,0 +1,16 @@
+#pragma once
+
+// Conversion from MIDI pitch codes to frequencies in Hz
+static const float pitchFrequency[] = {
+	   8.176,     8.662,     9.177,     9.723,    10.301,    10.913,    11.562,    12.250,    12.978,    13.750,    14.568,    15.434,
+	  16.352,    17.324,    18.354,    19.445,    20.602,    21.827,    23.125,    24.500,    25.957,    27.500,    29.135,    30.868,
+	  32.703,    34.648,    36.708,    38.891,    41.203,    43.654,    46.249,    48.999,    51.913,    55.000,    58.270,    61.735,
+	  65.406,    69.296,    73.416,    77.782,    82.407,    87.307,    92.499,    97.999,   103.826,   110.000,   116.541,   123.471,
+	 130.813,   138.591,   146.832,   155.563,   164.814,   174.614,   184.997,   195.998,   207.652,   220.000,   233.082,   246.942,
+	 261.626,   277.183,   293.665,   311.127,   329.628,   349.228,   369.994,   391.995,   415.305,   440.000,   466.164,   493.883,
+	 523.251,   554.365,   587.330,   622.254,   659.255,   698.456,   739.989,   783.991,   830.609,   880.000,   932.328,   987.767,
+	1046.502,  1108.731,  1174.659,  1244.508,  1318.510,  1396.913,  1479.978,  1567.982,  1661.219,  1760.000,  1864.655,  1975.533,
+	2093.005,  2217.461,  2349.318,  2489.016,  2637.020,  2793.826,  2959.955,  3135.963,  3322.438,  3520.000,  3729.310,  3951.066,
+	4186.009,  4434.922,  4698.636,  4978.032,  5274.041,  5587.652,  5919.911,  6271.927,  6644.875,  7040.000,  7458.620,  7902.133,
+	8372.018,  8869.844,  9397.273,  9956.063, 10548.082, 11175.303, 11839.822, 12543.854,
+};