[CMake] Move towards target-based CMake and partly fix picking up headers from an installed ROOT

CMakeLists.txt

@@ -12,6 +12,19 @@ if(WIN32)
   cmake_policy(SET CMP0091 OLD)
   set(CMAKE_SKIP_TEST_ALL_DEPENDENCY TRUE)
 endif()
+if(APPLE AND (NOT CMAKE_OSX_SYSROOT OR CMAKE_OSX_SYSROOT STREQUAL ""))
+  # The SYSROOT *must* be set before the project() call
+  execute_process(COMMAND xcrun --sdk macosx --show-sdk-path
+    OUTPUT_VARIABLE SDK_PATH
+    ERROR_QUIET
+    OUTPUT_STRIP_TRAILING_WHITESPACE)
+
+  if(NOT EXISTS "${SDK_PATH}")
+    message(FATAL_ERROR "Could not detect macOS SDK path")
+  endif()
+
+  set(CMAKE_OSX_SYSROOT "${SDK_PATH}" CACHE PATH "SDK path" FORCE)
+endif()
 
 if(CMAKE_SOURCE_DIR STREQUAL CMAKE_BINARY_DIR AND NOT ALLOW_IN_SOURCE)
   message(FATAL_ERROR
@@ -217,7 +230,7 @@ if(ccache)
 
   if(EXISTS ${CCACHE_COMMAND})
     message(STATUS "Found ccache: ${CCACHE_COMMAND}")
-    set_property(GLOBAL PROPERTY RULE_LAUNCH_COMPILE ${CCACHE_COMMAND})
+    set(CMAKE_CXX_COMPILER_LAUNCHER ${CCACHE_COMMAND} CACHE STRING "Path to ccache" FORCE)
     execute_process(COMMAND ${CCACHE_COMMAND} "-V" OUTPUT_VARIABLE CCACHE_VERSION)
     string(REGEX REPLACE "ccache version ([0-9\\.]+).*" "\\1" CCACHE_VERSION ${CCACHE_VERSION})
   else()

builtins/nlohmann/CMakeLists.txt

@@ -1,7 +1,12 @@
-# Install nlohmann/json.hpp include to have it
+# Install nlohmann/json.hpp and json_fwd.hpp
+# This file will define the target
+#   nlohmann_json
+# and the alias
+#   nlohmann_json::nlohmann_json
+# with proper #defines and includes. Use the alias target with the full prefix for access to JSON.
 
-# file only used when ACLiC or ROOT macros will include REve headers,
-# it is not used for ROOT compilation
+# The installed files are only used when ACLiC or ROOT macros will include REve headers,
+# they are not used for ROOT compilation, as this happens directly from the source directory.
 
 # extract version from existing header file
 file(STRINGS "json.hpp" JSON_H REGEX "^#define NLOHMANN_JSON_VERSION_[A-Z]+[ ]+[0-9]+.*$")
@@ -20,4 +25,15 @@ set_property(GLOBAL APPEND PROPERTY ROOT_BUILTIN_TARGETS builtin_nlohmann_json_i
 
 install(FILES ${CMAKE_SOURCE_DIR}/builtins/nlohmann/json.hpp DESTINATION ${CMAKE_INSTALL_INCLUDEDIR}/nlohmann/)
 
+# Create a target and all its configs:
+add_library(nlohmann_json INTERFACE)
 
+target_include_directories(nlohmann_json INTERFACE $<BUILD_INTERFACE:${CMAKE_SOURCE_DIR}/builtins> $<INSTALL_INTERFACE:include>)
+target_compile_definitions(nlohmann_json INTERFACE NLOHMANN_JSON_PROVIDES_FWD_HPP)
+
+install(TARGETS nlohmann_json
+  EXPORT ROOTExports)
+set_property(GLOBAL APPEND PROPERTY ROOT_EXPORTED_TARGETS nlohmann_json)
+
+# Alias, so can use it as drop-in replacement for system nlohmann_json.
+add_library(nlohmann_json::nlohmann_json ALIAS nlohmann_json)

builtins/openssl/CMakeLists.txt

@@ -56,6 +56,7 @@ set(OPENSSL_INCLUDE_DIRS ${OPENSSL_PREFIX}/include CACHE INTERNAL "" FORCE)
 set(OPENSSL_CRYPTO_LIBRARY ${OPENSSL_CRYPTO_LIBRARY} CACHE INTERNAL "" FORCE)
 set(OPENSSL_SSL_LIBRARY ${OPENSSL_SSL_LIBRARY} CACHE INTERNAL "" FORCE)
 set(OPENSSL_LIBRARIES ${OPENSSL_SSL_LIBRARY} ${OPENSSL_CRYPTO_LIBRARY} ${CMAKE_DL_LIBS} CACHE INTERNAL "" FORCE)
+set(OPENSSL_ROOT ${OPENSSL_PREFIX} CACHE INTERNAL "Location of the builtin OpenSSL installation" FORCE)
 
 # Dependent libraries might check for the existence of the include directories
 file(MAKE_DIRECTORY ${OPENSSL_INCLUDE_DIR})

builtins/xrootd/CMakeLists.txt

@@ -7,21 +7,10 @@
 include(ExternalProject)
 
 set(XROOTD_VERSION "5.8.0")
+set(XROOTD_PREFIX ${CMAKE_BINARY_DIR}/XROOTD-prefix)
 
-set(XROOTD_PREFIX ${CMAKE_BINARY_DIR})
 message(STATUS "Downloading and building XROOTD version ${XROOTD_VERSION}")
 
-list(REMOVE_ITEM XROOTD_CLIENT_LIBRARIES OpenSSL::SSL)
-list(REMOVE_ITEM XROOTD_UTILS_LIBRARIES OpenSSL::SSL)
-
-set(libname ${CMAKE_SHARED_LIBRARY_PREFIX}XrdCl${CMAKE_SHARED_LIBRARY_SUFFIX})
-list(APPEND XROOTD_CLIENT_LIBRARIES ${XROOTD_PREFIX}/lib/${libname})
-list(REMOVE_DUPLICATES XROOTD_CLIENT_LIBRARIES)
-
-set(libname ${CMAKE_SHARED_LIBRARY_PREFIX}XrdUtils${CMAKE_SHARED_LIBRARY_SUFFIX})
-list(APPEND XROOTD_UTILS_LIBRARIES ${XROOTD_PREFIX}/lib/${libname})
-list(REMOVE_DUPLICATES XROOTD_UTILS_LIBRARIES)
-
 ExternalProject_Add(
     BUILTIN_XROOTD
     URL http://lcgpackages.web.cern.ch/lcgpackages/tarFiles/sources/xrootd-${XROOTD_VERSION}.tar.gz
@@ -41,10 +30,11 @@ ExternalProject_Add(
                -DENABLE_CEPH=OFF
                -DXRDCL_LIB_ONLY=ON
                -DCMAKE_INSTALL_RPATH:STRING=${XROOTD_PREFIX}/lib
-               -DOPENSSL_ROOT_DIR=${OPENSSL_ROOT_DIR}
+               -DOpenSSL_ROOT=${OPENSSL_ROOT} #For CMake <3.27
+               -DOPENSSL_ROOT=${OPENSSL_ROOT}
     INSTALL_COMMAND ${CMAKE_COMMAND} --build . --target install
     LOG_DOWNLOAD 1 LOG_CONFIGURE 1 LOG_BUILD 1 LOG_INSTALL 1 LOG_OUTPUT_ON_FAILURE 1
-    BUILD_BYPRODUCTS ${XROOTD_CLIENT_LIBRARIES} ${XROOTD_UTILS_LIBRARIES}
+    BUILD_BYPRODUCTS XrdUtils XrdCl
     TIMEOUT 600
 )
 
@@ -55,22 +45,19 @@ if(builtin_openssl)
   add_dependencies(BUILTIN_XROOTD OPENSSL)
 endif()
 
-list(APPEND XROOTD_CLIENT_LIBRARIES OpenSSL::SSL)
-list(REMOVE_DUPLICATES XROOTD_CLIENT_LIBRARIES)
-list(APPEND XROOTD_UTILS_LIBRARIES OpenSSL::SSL)
-list(REMOVE_DUPLICATES XROOTD_UTILS_LIBRARIES)
-
 set(XROOTD_INCLUDE_DIRS ${XROOTD_PREFIX}/include/xrootd CACHE INTERNAL "" FORCE)
-set(XROOTD_CLIENT_LIBRARIES ${XROOTD_CLIENT_LIBRARIES} CACHE INTERNAL "" FORCE)
-set(XROOTD_UTILS_LIBRARIES ${XROOTD_UTILS_LIBRARIES} CACHE INTERNAL "" FORCE)
+set(XRDCL_NAME ${CMAKE_SHARED_LIBRARY_PREFIX}XrdCl${CMAKE_SHARED_LIBRARY_SUFFIX})
+set(XRDUTILS_NAME ${CMAKE_SHARED_LIBRARY_PREFIX}XrdUtils${CMAKE_SHARED_LIBRARY_SUFFIX})
+set(XROOTD_CLIENT_LIBRARIES ${XROOTD_PREFIX}/lib/${XRDCL_NAME} CACHE INTERNAL "" FORCE)
+set(XROOTD_UTILS_LIBRARIES ${XROOTD_PREFIX}/lib/${XRDUTILS_NAME} CACHE INTERNAL "" FORCE)
+set(XROOTD_LIBRARIES ${XROOTD_PREFIX}/lib/${XRDCL_NAME} CACHE INTERNAL "" FORCE)
 
-list(APPEND CMAKE_BUILD_RPATH ${XROOTD_PREFIX}/lib)
-add_dependencies(XRootD BUILTIN_XROOTD)
+install(DIRECTORY ${XROOTD_PREFIX}/lib/ DESTINATION ${CMAKE_INSTALL_LIBDIR} COMPONENT libraries FILES_MATCHING PATTERN "libXrd*")
+install(DIRECTORY ${XROOTD_PREFIX}/include/xrootd/ DESTINATION ${CMAKE_INSTALL_INCLUDEDIR}/xrootd COMPONENT headers)
+set(CMAKE_BUILD_RPATH ${CMAKE_BUILD_RPATH} ${XROOTD_PREFIX}/lib PARENT_SCOPE)
 
 set_property(GLOBAL APPEND PROPERTY ROOT_BUILTIN_TARGETS BUILTIN_XROOTD)
 
-install(DIRECTORY ${XROOTD_PREFIX}/lib/ DESTINATION ${CMAKE_INSTALL_LIBDIR} COMPONENT libraries FILES_MATCHING PATTERN "libXrd*")
-install(DIRECTORY ${XROOTD_PREFIX}/include/xrootd/ DESTINATION ${CMAKE_INSTALL_INCLUDEDIR}/xrootd COMPONENT headers)
 if(APPLE)
   # XRootD libraries on mac need the LC_RPATH variable set. The build process already takes care of setting
   #   * BUILD_RPATH = build/XROOTD-prefix/../src
@@ -81,3 +68,4 @@ if(APPLE)
           CODE "xrootd_libs_change_rpath(${XROOTD_PREFIX}/lib ${CMAKE_INSTALL_FULL_LIBDIR})"
   )
 endif()
+

cmake/modules/FindVdt.cmake

@@ -13,8 +13,7 @@
 # Imported Targets
 # ^^^^^^^^^^^^^^^^
 #
-# This module defines :prop_tgt:`IMPORTED` target ``VDT::VDT``,
-# if Vdt has been found.
+# VDT::VDT if Vdt has been found.
 #
 # Result Variables
 # ^^^^^^^^^^^^^^^^
@@ -42,8 +41,6 @@ if(NOT VDT_LIBRARY)
   find_library(VDT_LIBRARY NAMES vdt)
 endif()
 
-mark_as_advanced(VDT_INCLUDE_DIR VDT_LIBRARY)
-
 if(VDT_INCLUDE_DIR)
   file(STRINGS "${VDT_INCLUDE_DIR}/vdt/vdtMath.h" VDT_H REGEX "^#define VDT_VERSION_[A-Z]+[ ]+[0-9]+.*$")
   string(REGEX REPLACE ".+VDT_VERSION_MAJOR[ ]+([0-9]+).*$" "\\1" VDT_VERSION_MAJOR "${VDT_H}")
@@ -59,9 +56,14 @@ if(VDT_INCLUDE_DIR)
   endif()
 endif()
 
+# Don't show in GUI
+mark_as_advanced(VDT_FOUND VDT_VERSION VDT_INCLUDE_DIR VDT_LIBRARY)
+
 include(FindPackageHandleStandardArgs)
-find_package_handle_standard_args(Vdt FOUND_VAR VDT_FOUND
-  REQUIRED_VARS VDT_INCLUDE_DIR VDT_LIBRARY VERSION_VAR VDT_VERSION)
+find_package_handle_standard_args(Vdt
+  REQUIRED_VARS VDT_INCLUDE_DIR VDT_LIBRARY
+  VERSION_VAR VDT_VERSION)
+
 
 if(VDT_FOUND)
   set(VDT_INCLUDE_DIRS ${VDT_INCLUDE_DIR})
@@ -71,12 +73,12 @@ if(VDT_FOUND)
   endif()
 
   if(NOT TARGET VDT::VDT)
-    add_library(VDT::VDT UNKNOWN IMPORTED)
+    add_library(VDT::VDT SHARED IMPORTED)
+    target_include_directories(VDT::VDT SYSTEM INTERFACE ${VDT_INCLUDE_DIRS})
 
     set_target_properties(VDT::VDT
       PROPERTIES
         IMPORTED_LOCATION "${VDT_LIBRARY}"
-        INTERFACE_INCLUDE_DIRECTORIES "${VDT_INCLUDE_DIRS}"
     )
   endif()
 endif()